Through the Interface

#light

module Mandelbrot

#I @"C:\Program Files\Autodesk\AutoCAD 2009"

#r "acdbmgd.dll"

#r "acmgd.dll"

#nowarn "57"

open Autodesk.AutoCAD.Runtime

open Autodesk.AutoCAD.ApplicationServices

open Autodesk.AutoCAD.EditorInput

open Autodesk.AutoCAD.DatabaseServices

open Autodesk.AutoCAD.Geometry

open System

open Microsoft.FSharp.Math

let maxIteration = 50

let granularity = 400

let modSquared (c : Complex) = c.r * c.r + c.i * c.i

type MandelbrotResult =

    | DidNotEscape

    | Escaped of int

let mandelbrot c =

  let rec mandelbrotInner z iterations =

    if(modSquared z >= 4.0)

      then Escaped iterations

    elif iterations = maxIteration

      then DidNotEscape

    else mandelbrotInner ((z * z) + c) (iterations + 1)

  mandelbrotInner c 0

[<CommandMethod("MB")>]

let drawMandelbrot () =

  let doc =

    Application.DocumentManager.MdiActiveDocument

  let ed = doc.Editor

  let db = doc.Database

  let tm = doc.TransactionManager

  use tr =

    tm.StartTransaction()

  // Get appropriately-typed BlockTable and BTR

  let bt =

    tr.GetObject

      (db.BlockTableId,OpenMode.ForRead)

    :?> BlockTable

  let ms =

    tr.GetObject

      (bt.[BlockTableRecord.ModelSpace],

      OpenMode.ForWrite)

    :?> BlockTableRecord

  // Now let's create our geometry

  let xgran = 1.0 / Int32.to_float granularity

  let ygran = 1.0 / Int32.to_float granularity

  for y in [-1.0..xgran..1.0] do

    for x in [-2.0..ygran..1.0] do

      match mandelbrot (Complex.Create (x, y)) with

      | DidNotEscape ->

        let pt =

          new Solid

            (new Point3d(x,y,0.0),

             new Point3d(x+xgran,y,0.0),

             new Point3d(x,y+ygran,0.0),

             new Point3d(x+xgran,y+ygran,0.0))

        ms.AppendEntity(pt) |> ignore

        tr.AddNewlyCreatedDBObject(pt, true)

      | Escaped _ -> ()

    tm.QueueForGraphicsFlush()

    tm.FlushGraphics()

    ed.UpdateScreen()

  tr.Commit()